$
\def\ed{\stackrel{\text{def}}{=}}
\def\op{\big(}
\def\cp{\big)}
$
Here's a proof that both players' choosing a stopping threshold of $\ 87\ $ any time they receive the dice is a Nash equilibrium, as conjectured by user3257842 in a comment. The equilibrium expected payoffs, rounded correctly to eight decimal places are $\ 48.57477898\ $ for player $\ A\ $ and $\ 41.04042506\ $ for player $\ B\ .$ The exact expected payoffs are actually rational numbers, but with numerators and denominators of $175$ decimal digits and $173$ decimal digits, respectively.
To prove the result, it's sufficient to show that if player $\ B\ $ always chooses a stopping threshold of $\ 87\ ,$ then player $\ A$'s best strategy is to do the same. It immediately follows from this that if player $\ A\ $ always chooses a stopping threshold of $\ 87\ $ then player $\ B$'s best strategy is also to do the same, because as soon as player $\ B\ $ receives the dice, he or she will be in exactly the same position as player $\ A\ $ was at the start of the game.
Let $\ \sigma_s\ $ be the probability either player will successfully reach a stopping threshold of $\ S\ $ in a single series of rolls given that his or her currently accumulated sum is $\ s\ .$ Then $\ \sigma_s\ $ satisfies the following recursion
$$
\sigma_{s-1}=\frac{1}{10}\sum_{i=0}^8\sigma_{s+i}
$$
and boundary condition
$$
\sigma_s=1
$$
for $\ s\in\{S,S+1,\dots,S+8\,\}\ ,$ and $\ \sigma_0\ $ is the probability that the player will reach the threshold from the start of the series of rolls. If
$$
C\ed\pmatrix{\frac{1}{10}&\frac{1}{10}&\dots&\frac{1}{10}&\frac{1}{10}\\
1&0&\dots&0&0\\
0&1&\dots&0&0\\
\vdots&&\ddots&\vdots&\vdots\\
0&0&\dots&1&0}
$$
is the companion matrix of the recursion, then
$$
\pmatrix{\sigma_{s-1}\\\sigma_s\\\vdots\\\sigma_{s+7}}=C\pmatrix{\sigma_s\\\sigma_{s+1}\\\vdots\\\sigma_{s+8}}\ ,
$$
and
$$
\sigma_0=\boldsymbol{\epsilon}_1^TC^S\mathbf{1}\ ,
$$
where $\ \boldsymbol{\epsilon}_1\ $ is the first column of the $\ 9\times9\ $ identity matrix and $\ \mathbf{1}\ $ the $\ 9\times1\ $ matrix all of whose entries are $1.$
Let
\begin{align}
\sigma_*&\ed\boldsymbol{\epsilon}_1^TC^{87}\mathbf{1}\\
&\approx0.1551083521
\end{align}
be the probability of a player's reaching a stopping threshold of $87$ in a single series of rolls.
If player $\ B\ $ always chooses a stopping threshold of $\ 87\ ,$ then one can treat player $\ A$'s problem as effectively playing a single-player game which terminates with probability $\ \sigma_*\ $ whenever he or she rolls a zero, or restarts from scratch with probability $\ 1-\sigma_*\ $ and with player $\ A$'s cumulative sum being reset to zero. In this latter case, player $\ A\ $ will be in exactly the same position as at the start of the game, so the optimal stopping threshold $\ S_a\ $ and optimal expected value $\ v_a\ ,$ say, will always be the same whenever that position is reached. Let $\ \alpha_s\ $ be player $\ A$'s expected payoff given that he or she has currently accumulated a sum of $\ s\ $ in a single series of rolls in this single player game. Then $\ \alpha_s\ $ satisfies the following recursion:
$$
\alpha_{s-1}=\frac{(1-\sigma_*)v_a+\sum_\limits{i=0}^8\alpha_{s+i}}{10}\label{1}\tag{1}
$$
and boundary conditions
$$
\alpha_s=s
$$
for $\ s\in\{S_a,S_a+1,\dots,S_a+8\,\}\ ,$ and $\ v_a=\alpha_0\ .$ Subtracting $\ (1-\sigma_*)v_a\ $ from both sides of identity \eqref{1} gives
$$
\alpha_{s-1}-(1-\sigma_*)v_a=\frac{\sum_\limits{i=0}^8\op\alpha_{s+i}-(1-\sigma_*)v_a\cp}{10}\ ,
$$
so $\ \alpha_{s-1}-(1-\sigma_*)v_a\ $ satisfies the same recursion as $\ \sigma_s\ ,$ but with different boundary conditions. Therefore
\begin{align}
v_a&=\alpha_0\\
&=\boldsymbol{\epsilon}_1^TC^{S_a}\op\op S_a-(1-\sigma_*)v_a\cp\mathbf{1}+\boldsymbol{k}\cp+(1-\sigma_*)v_a\\
&=\op S_a-(1-\sigma_*)v_a\cp\boldsymbol{\epsilon}_1^TC^{S_a}\mathbf{1}+\boldsymbol{\epsilon}_1^TC^{S_a}\boldsymbol{k}+(1-\sigma_*)v_a\
\end{align}
where
$$
\boldsymbol{k}\ed\pmatrix{0\\1\\\vdots\\8}\ .
$$
Solving this linear equation for $\ v_a\ $ gives
$$
v_a=\frac{S_a\boldsymbol{\epsilon}_1^TC^{S_a}\mathbf{1}+\boldsymbol{\epsilon}_1^TC^{S_a}\boldsymbol{k}}{\sigma_*+(1-\sigma_*)\boldsymbol{\epsilon}_1^TC^{S_a}\mathbf{1}}\ .\tag{2}\label{2}
$$
The following Magma script, which can be run by copying and pasting it into the online Magma calculator and clicking the Submit button, evaluates the expression on the right side of the above equation in exact rational arithmetic for every value of $\ S_a\ $ from $\ S_a=1\ $ to $\ S_a=150\ ,$ and verifies that its maximum value for $\ S_a\ $ in that range occurs at $\ S_a=87\ ,$ and, rounded to eight decimal places, is $\ 48.57477898\ .$
C:=Matrix(Rationals(),9,9,
[1/10,1/10,1/10,1/10,1/10,1/10,1/10,1/10,1/10,
1,0,0,0,0,0,0,0,0,
0,1,0,0,0,0,0,0,0,
0,0,1,0,0,0,0,0,0,
0,0,0,1,0,0,0,0,0,
0,0,0,0,1,0,0,0,0,
0,0,0,0,0,1,0,0,0,
0,0,0,0,0,0,1,0,0,
0,0,0,0,0,0,0,1,0]);
ones:=Matrix(Rationals(),9,1, [1,1,1,1,1,1,1,1,1]);
Sb:=87;
sigvec:=C^Sb*ones;
sigma:=sigvec[1,1];
maxva:=0/1;
for S in [1..150] do
d:=Matrix(Rationals(),9,1,[S,S+1,S+2,S+3,S+4,S+5,S+6,S+7,S+8]);
e:=C^S*d;
pim:=C^S*ones;
va:=e[1,1]/(sigma+(1-sigma)*pim[1,1]);
if va gt maxva then
maxva:=va;
argmaxva:=S;
end if;
end for;
print(argmaxva);
print(RealField(10)!maxva);
print(RealField(10)!((1-sigma)*maxva));
print(RealField(10)!sigma);
This doesn't quite prove the result, because there remains a possibility that a value of $\ S_a\ $ greater than $\ 150\ $ might result in a larger value for the expression on the right side of equation \eqref{2}. This can be ruled out, however, by expressing $\ v_a\ $ in terms of the eigenvalues and eigenvectors of $\ C\ $ and appealing to the dominance of its Perron-Frobenius eigenvalue for sufficiently large values of $\ S_a\ .$ The matrix $\ C\ $ is a primitive matrix with non-negative entries, one real (Perron-Frobenius) eigenvalue $\ \lambda_1\approx$$\,0.9794303016 \ ,$ and four distinct complex conjugate pairs $\ \lambda_2,$$\,\lambda_3=\overline{\lambda_2},$$\,\lambda_4,$$\,\lambda_5=\overline{\lambda_4},$$\,\lambda_6,$$\,\lambda_7=\overline{\lambda_6},$$\,\lambda_8\ $ and $\ \lambda_9=\overline{\lambda_8}\ $ of eigenvalues, all of whose moduli do not exceed $\ 0.781\ .$ The matrix $\ C^S\ $ can be expanded as
\begin{align}
C^S&=\sum_{i=1}^9\lambda_i^S\boldsymbol{r}_i\boldsymbol{\ell}_i^T\\
&=\lambda_1^S\left(\boldsymbol{r}_1\boldsymbol{\ell}_1^T+\sum_{i=2}^9\left(\frac{\lambda_i}{\lambda_ 1}\right)^S\boldsymbol{r}_i\boldsymbol{\ell}_i^T \right)\ ,
\end{align}
where $\ \boldsymbol{r}_i\ $ and $\ \boldsymbol{\ell}_i^T\ $ are unit right and left eigenvectors, respectively, of $\ C\ $ corresponding to the eigenvalue $\ \lambda_i\ ,$ with $\ \boldsymbol{r}_1\ge\mathbf{0}\ $ and $\ \boldsymbol{\ell}_1\ge\mathbf{0}\ .$ For sufficiently large values of $\ S\ ,$ the sum $\ \sum_\limits{i=2}^9\left(\frac{\lambda_i}{\lambda_ 1}\right)^S\boldsymbol{r}_i\boldsymbol{\ell}_i^T \ $ becomes utterly negligible with respect to $\ \boldsymbol{r}_1\boldsymbol{\ell}_1^T\ ,^\color{red}{\dagger}\ $ so, to a very good approximation,
$$
C^S\approx\lambda_1^S\boldsymbol{r}_1\boldsymbol{\ell}_1^T
$$
and
\begin{align}
v_a&\approx \frac{\boldsymbol{\epsilon}_1^T\boldsymbol{r}_1\lambda_1^{S_a}\op\boldsymbol{\ell}_1^T\mathbf{1}S_a+\boldsymbol{\ell}_1^T\boldsymbol{k}\cp}{\sigma_*+(1-\sigma_*)\boldsymbol{\epsilon}_1^TC^{S_a}\mathbf{1}}\\
&<\sigma_*^{-1}\boldsymbol{\epsilon}_1^T\boldsymbol{r}_1\lambda_1^{S_a}\op\boldsymbol{\ell}_1^T\mathbf{1}S_a+\boldsymbol{\ell}_1^T\boldsymbol{k}\cp\\
\end{align}
The derivative of the function $\ \lambda_1^{S_a}\op\boldsymbol{\ell}_1^T\mathbf{1}S_a+\boldsymbol{\ell}_1^T\boldsymbol{k}\cp\ $ is positive for $\ S_a<-\frac{1}{\ln\lambda_1}-\frac{ \boldsymbol{\ell}_1^T\boldsymbol{k}}{\boldsymbol{\ell}_1^T\mathbf{1}}\approx45.5\ ,$ zero at $\ S_a=-\frac{1}{\ln\lambda_1}-\frac{ \boldsymbol{\ell}_1^T\boldsymbol{k}}{\boldsymbol{\ell}_1^T\mathbf{1}}\ $ and negative for $\ S_a>-\frac{1}{\ln\lambda_1}-\frac{ \boldsymbol{\ell}_1^T\boldsymbol{k}}{\boldsymbol{\ell}_1^T\mathbf{1}}\ ,$ so the function itself is certainly decreasing for $\ S_a\ge150\ .$ For such vales of $\ S_a\ ,$ therefore,
\begin{align}
v_a&<\sigma_*^{-1}\boldsymbol{\epsilon}_1^T\boldsymbol{r}_1\lambda_1^{150}\op150\,\boldsymbol{\ell}_1^T\mathbf{1}+\boldsymbol{\ell}_1^T\boldsymbol{k}\cp\\
&\approx47.7\ .
\end{align}
Since this is less than the value of $\ v_a\ $ at $\ S_a=87\ ,$ it follows that the latter is the maximum over all positive integral values of $\ S_a\ .$
Player $\ A\ $ will succeed in reaching the stopping threshold of $\ 87\ $ with probability $\ \sigma_*\ ,$ and fail to do so with probability $\ 1-\sigma_*\ .$ In the later case, player $\ B\ $ will be in the same situation that player $\
A\ $ was at the beginning of the game, so his or her expected payoff, given that that situation has occurred, will be $\ v_a\ .$ His or her expected payoff, $\ v_b\ ,$ for the game itself is therefore given by
\begin{align}
v_b&=\sigma_*0+\op1-\sigma_*\cp v_a\\
&\approx41.04042506\ .
\end{align}
For the sake of completeness, I have below included the Magma script I used to calculate the eigenvalues and eigenvectors of $\ C\ $ and the bound on $\ v_a\ $ for $\ S_a\ge150\ .$ Note that the Perron-Frobenius eigenvalue is the eighth in the list returned by Magma in this code, not the first.
$\color{red}{\dagger}$ For $\ S\ge100\ ,$ for instance, $\ \left|\frac{\lambda_i}{\lambda_ 1}\right|^S<1.5\times10^{-10}\ .$
CC:=Matrix(ComplexField(20),9,9,
[1/10,1/10,1/10,1/10,1/10,1/10,1/10,1/10,1/10,
1,0,0,0,0,0,0,0,0,
0,1,0,0,0,0,0,0,0,
0,0,1,0,0,0,0,0,0,
0,0,0,1,0,0,0,0,0,
0,0,0,0,1,0,0,0,0,
0,0,0,0,0,1,0,0,0,
0,0,0,0,0,0,1,0,0,
0,0,0,0,0,0,0,1,0]);
e9:=Matrix(ComplexField(20),9,1,[0,0,0,0,0,0,0,0,1]);
ones:=Matrix(ComplexField(20),9,1,[1,1,1,1,1,1,1,1,1]);
k:=Matrix(ComplexField(20),9,1, [0,1,2,3,4,5,6,7,8]);
ident:=ScalarMatrix(ComplexField(20),9,1.0);
U:=ZeroMatrix(ComplexField(20),9,9);
evs:=Eigenvalues(CC);
for i in [1..9] do
ev:=evs[i,1];
m:=CC-ev*ident;
for j in [1..9] do
m[9,j]:=1.0;
end for;
evec:=m^(-1)*e9;
norm:=0.0;
for j in [1..9] do
norm:=norm+Modulus(evec[j,1])^2;
end for;
norm:=Sqrt(norm);
for j in [1..9] do
U[j,i]:=(1/norm)*evec[j,1];
end for;
end for;
r1:=ColumnSubmatrix(U,8,1);
ell1:=ColumnSubmatrix(Transpose(U^(-1)),8,1);
eps1r1:=Modulus(r1[8,1]);
ell1t1:=Transpose(ell1)*ones;
ell1t1:=Modulus(ell1t1[1,1]);
ell1tk:=Transpose(ell1)*k;
ell1tk:=Modulus(ell1tk[1,1]);
lam1:=Modulus(evs[8,1]);
sigma:=CC^87*ones;
sigma:=Modulus(sigma[1,1]);
print(-1/Log(lam1)-ell1tk/ell1t1);
print(sigma^(-1)*eps1r1*lam1^150*(ell1t1*150+ell1tk));